|
안녕하세요...
민성기 입니다.
어제는 제가 '몸살'이 나서~ 강좌를 쉬는 만행을~~ ^^;
드디어 실전이구만요~~
*** 실전~
자, 드디어 기다리고 기다리던 시간이다. 이제 직접 갈구리를 휘둘러 볼 때가 왔다. 이 강좌에서는 WH_KEYBOARD와 WH_SHELL이라는 두 개의 갈구리를 이용해 키보드의 동작과 노트패드의 실행을 마음껏 괴롭혀 볼 것이다. 위에서도 설명 했지만 시스템 전체를 상대로 맞짱을 뜨기 위해서는 훅 프로시저가 DLL내에 있어야 한다. 혹시 DLL을 만들줄 모르는 사람이 있다면 조 아래 용길님의 ‘델파이로 DLL 만들고 사용하기’라는 멋진 강좌가 있으니 빠른 시간내에 읽고 습득하여 자신의 것으로 만들자. (아~ 이 얼마나 훌륭한 떠넘기기 인가~ ^^;)
델파이의 ‘New’ 메뉴를 선택해 ‘DLL’ 프로젝트를 하나 시작하고, 프로젝트 이름을 ‘HookDLL.DPR’로 저장하자. 갈구리질용 함수를 사용하기 위해서는 먼저 Uses문에 Windows와 Messages를 포함시켜야 한다.
uses SysUtils, Classes, Windows, Messages;
키보드와 셀의 훅 핸들을 저장할 두개의 전역변수를 만들어 두자.
var
HKbHook : HHOOK;
HShellHook : HHOOK;
앞에서 말했듯이, 이 전역변수들은 DLL 내의 훅 프로시저가 호출될 때마다 다른 어플리케이션의 영역에 있기 때문에 어떤값을 가지고 있을지는 아무도 모른다. (물론, 일반적으로는 0일 것이다.) 따라서 각 어플리케이션과 무관한 영역에 이 값을 저장하고 불러와야 한다. 여기서는 그 영역을 하드디스크 내의 ‘C:\Hook.dat’파일로 하자. 이제 이 파일에 파일에 훅 데이터를 읽고 써주는 프로시저, ReadData와 WriteData를 만들자.
Const
HookDataFile = ‘c:\Hook.Dat’;
procedure ReadData;
var
F : TFileStream;
begin
F := TFileStream.Create(HookDataFile, fmOpenRead);
try
F.Read(HKbHook, sizeof(HKbHook));
F.Read(HShellHook, sizeof(HShellHook));
finally
F.Free;
end;
end;
procedure WriteData;
var
F : TFileStream;
begin
F := TFileStream.Create(HookDataFile, fmCreate);
try
F.Write(HKbHook, sizeof(HKbHook));
F.Write(HShellHook, sizeof(HShellHook));
finally
F.Free;
end;
end;
각 어플리케이션에서 이 DLL이 호출될 때, 일반적으로 위의 전역변수 값은 0이다. 그러나 누가 알겠는가~?? 불의의 사고로 인해 0이 아닌 쓰레기값이 들어갈 수도 있다. 영화에서도 보면 그렇다. 다 죽은줄 알았던 주인공이 ‘끄응~’하고 살아나 영화 끝날때까지 악당을 괴롭힌다. 이 악당~ 자기가 게을러서 그렇게 된 것이므로 어디가서 하소연도 하지 못한다. 따라서 우리 역시 불쌍한 악당꼴이 되지 않기 위해서는 언제나 ‘확인사살’을 확실히 해야 한다. 초기에 두개의 훅핸들 전역변수를 0으로 해 주자.
begin
HKbHook := 0;
HShellHook := 0;
end.
이제 키보드 동작에 대한 갈구리질을 정의하자. 키보드를 먹통으로 만들어, 키보드 위에 라면남비를 올려놓고 라면을 먹는 것이 이 갈구리질의 목적이다.
{ 갈구리질 프로시저 }
function MyKBHook(Code : Integer; wParam : WPARAM; lParam : LPARAM) : LongInt; stdcall;
begin
{ 파일에 저장된 훅핸들을 읽어온다. }
if HKbHook = 0 then
ReadData;
{ Code값이 0보다 크거나 같을때만 }
{ 갈구리질을 하는 것이 요령. }
if Code >= 0 then
begin
{ 키보드를 몽땅 안눌리게 하자. }
{ 다음 훅체인이 불리지 않도록 하면 끝~! }
Result := Integer(True);
Exit;
end;
Result := CallNextHookEx(HKbHook, Code, wParam, lParam);
end;
{ 키보드 갈구리 찍기 }
function HookKB : Boolean;
begin
HKbHook := SetWindowsHookEx( WH_KEYBOARD, MyKBHook, HInstance, 0);
Result := Boolean(HKbHook);
{ 파일에 훅핸들 쓰기 }
WriteData;
end;
{ 키보드 갈구리 뽑기 }
function UnHookKB : Boolean;
begin
{ 파일에 저장된 훅핸들을 읽어온다. }
if HKbHook = 0 then
ReadData;
Result := UnhookWindowsHookEx(HKbHook);
end;
갈구리를 찍고 뽑는 방법, 그리고 갈구리를 휘두르는 방법에 대한 개념이 어렵지 않게 이해 되었을 것이다. 이번엔 마찬가지 방법으로 ‘메모장’의 실행을 모니터하는 갈구리를 하나 더 만들어 보자.
{ 셀 갈구리질 }
function MyShellHook(Code : Integer; wParam : WPARAM; lParam : LPARAM) : LongInt; stdcall;
var
Buff : array [0..255] of Char;
s : String;
begin
{ 파일에 저장된 훅핸들을 읽어온다. }
if HShellHook = 0 then
ReadData;
{ 윈도우의 생성과 소멸만 괴롭힌다. 자세한 내용은 도움말을 참조할 것. }
if (code = HSHELL_WINDOWCREATED) or
(code = HSHELL_WINDOWDESTROYED) then
begin
{ 윈도우의 클래스명을 읽어온다. Code값이 위의 두개의 값일
경우, wParam은 윈도우의 핸들값이 된다. }
GetClassName(wParam, Buff, SizeOf(Buff));
{ 클래스명이 노트패드라면 메시지박스 보여주기. }
if Buff = 'Notepad' then
begin
if (code = HSHELL_WINDOWCREATED) then
S := '메모장이 실행되는구만요~!'
else
S := '메모장이 끝났구만요~!';
MessageBox(0,PChar(S),'Hook Message',0);
end;
end;
{ 다음 훅체인 호출 }
Result := CallNextHookEx(HShellHook, Code, wParam, lParam);
end;
{ 셀 갈구리 찍기 }
function HookSHELL : Boolean;
begin
HShellHook := SetWindowsHookEx( WH_SHELL, MyShellHook, HInstance, 0);
Result := Boolean(HShellHook);
{ 파일에 훅핸들 쓰기 }
WriteData;
end;
{ 셀 갈구리 뽑기 }
function UnHookSHELL : Boolean;
begin
{ 파일에 저장된 훅핸들을 읽어온다. }
if HShellHook = 0 then
ReadData;
Result := UnhookWindowsHookEx(HShellHook);
end;
이제, 갈구리를 찍고 뽑는 함수들을 외부에서 사용할 수 있도록 Exports 구문에 추가해 주자.
Exports
HookKB, HookSHELL, UnHookKB, UnHookSHELL;
이것으로 훅용 DLL이 완성되었다. 컴파일 하면 ‘Hookdll.DLL’ 파일이 생길 것이다. 이제 이 DLL을 사용해 갈구리를 찍고 해제하는 간단한 프로그램을 만들어 보자. 새로운 어플리케이션을 시작하고 Hookdll.DLL’내의 함수들을 다음과 같이 임포트 한다.
function HookKB : Boolean; external 'HookDll.dll';
function UnHookKB : Boolean; external 'HookDll.dll';
function HookSHELL : Boolean; external 'HookDll.dll';
function UnHookSHELL : Boolean; external 'HookDll.dll';
버튼을 네 개 올려놓고 이름을 각각 HookKBBtn, HookShellBtn, UnHookKBBtn, UnHookShellBtn 이라고 짓자. 앞의 두 버튼의 Enabled 속성을 꺼주고 각 버튼들의 OnClick이벤트 프로시저를 다음과 같이 작성해 준다.
procedure TForm1.HookKBBtnClick(Sender: TObject);
begin
if HookKB then
begin
HookKBBtn.Enabled := false;
UnHookKBBtn.Enabled := True;
end;
end;
procedure TForm1.HookShellBtnClick(Sender: TObject);
begin
if HookShell then
begin
HookShellBtn.Enabled := false;
UnHookShellBtn.Enabled := True;
end;
end;
procedure TForm1.UnHookKBBtnClick(Sender: TObject);
begin
if UnHookKB then
begin
HookKBBtn.Enabled := True;
UnHookKBBtn.Enabled := False;
end;
end;
procedure TForm1.UnHookShellBtnClick(Sender: TObject);
begin
if UnHookShell then
begin
HookShellBtn.Enabled := True;
UnHookShellBtn.Enabled := False;
end;
end;
이제 컴파일 후 실행해 보자. 키보드 훅을 동작시키면 키보드 위에 라면냄비를 올려놓고 먹을 수 있다. 셀 훅을 동작시킨다면 ‘메모장’이 실행되고 끝날 때마다 메시지박스가 나타날 것이다. 눈치 빠른 사람은 키보드 훅으로 키보드 전체를 먹통으로 만들어도 Alt-Tab 이나 Ctrl-Alt-Del 같은 키조합이 막히지 않는다는 것을 발견했을 것이다. 윈도우는 이러한 시스템 키조합을 갈구리질로부터 보호하고 있기 때문인데, 이것조차 막아버리기 희망하는 엽기적 프로그래머는 팁 게시판에 올라와 있는 영재님의 글을 참고로 하자.
*** 맺으며~
메모장의 실행을 모니터하고 키보드를 먹통으로 만드는 간단한 갈구리 프로그램을 만들어 보았다. 갈구리를 쓴다는 것은 것은 메시지 흐름을 손에 쥐는 것이다. 이제 조금이라도 껄떡대는 메시지가 눈에 띈다면 잡아서 족치고 볼 것이다. 수 틀리면 위의 키보드 훅처럼 전달하지 않고 삽으로 묻어버리는 일도 종종 발생할 것이다.
그러니 부디 머리도 자주 감고 발도 자주 닦아 개인 위생 및 정신건강을 바로잡고 맨정신으로 다가오는 21세기를
|
[이전 민성기님의 후킹 강좌] #3
